package 
{
	import ca.newcommerce.youtube.reference.SearchOrder;
	import ca.newcommerce.youtube.reference.SearchRacy;
	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;
	import flash.system.Security;
 
	import ca.newcommerce.youtube.data.ThumbnailData;
	import ca.newcommerce.youtube.data.VideoData;
	import ca.newcommerce.youtube.events.VideoFeedEvent;
	import ca.newcommerce.youtube.feeds.VideoFeed;
	import ca.newcommerce.youtube.iterators.ThumbnailIterator;
	import ca.newcommerce.youtube.webservice.YouTubeFeedClient;	
 
	/**
	 * ...
	 * @author Martin Legris ( http://blog.martinlegris.com )
	 */
	public class Main extends Sprite 
	{
		protected var _ws:YouTubeFeedClient;
		protected var _requestId:Number;
		protected var _player:Object = null;
		protected var _video:VideoData = null;
		protected var _playerLoader:Loader;
 
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			testSearch();
			loadPlayer();
		}
 
		protected function loadPlayer():void
		{
			trace("loadPlayer");
			_playerLoader = new Loader();
			_playerLoader.contentLoaderInfo.addEventListener(Event.INIT, onLoaderInit);
			_playerLoader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3"));
		}
 
		protected function onLoaderInit(evt:Event):void
		{
			trace("onLoaderInit");
 
			addChild(_playerLoader);
			var c:DisplayObject = _playerLoader.content;
			c.addEventListener("onReady", onPlayerReady);
			c.addEventListener("onError", onPlayerError);
			c.addEventListener("onStateChange", onPlayerStateChange);
			c.addEventListener("onPlaybackQualityChange", onVideoPlaybackQualityChange);
		}
 
		protected function onPlayerReady(evt:Event):void
		{
			trace("onPlayerReady");
 
			_player = _playerLoader.content;
			_player.setSize(480, 360);
			if (_video != null)
				startPlaying();
		}
 
		protected function onPlayerError(evt:Event):void
		{
			trace("onPlayerError:" + Object(evt).data);
		}
 
		protected function onPlayerStateChange(evt:Event):void
		{
			trace("onPlayerStateChange:" + Object(evt).data);
		}
 
		protected function onVideoPlaybackQualityChange(evt:Event):void
		{
			trace("onVideoPlaybackQualityChange:" + Object(evt).data);
		}
 
		protected function testSearch():void
		{
			Security.allowDomain("www.youtube.com");
 
			_ws = YouTubeFeedClient.getInstance();
 
			_ws.addEventListener(VideoFeedEvent.VIDEO_DATA_RECEIVED, doSearchResults);
			_requestId = _ws.getVideos("american idol", "", null, null, ["music"], ["male"], SearchOrder.ORDER_BY_VIEWCOUNT, SearchRacy.RACY_INCLUDE);
 
			_ws.getVideos("music video");
		}
 
		protected function doSearchResults(evt:VideoFeedEvent):void
		{
			if(_requestId == evt.requestId)
			{
				var feed:VideoFeed = evt.feed;
				_video = feed.getAt(2);
			}
			else
			{
				trace("this call:"+evt.requestId+" isn't ours. We'll wait for the next one...");
			}
 
			if (_player != null)
			{
				startPlaying();
			}
		}
 
		protected function startPlaying():void
		{
			var id:String = _video.id;
			id = id.substr(id.lastIndexOf("/") + 1);
			trace("loading video by id:" + id);
			trace("loading video:" + _video.actualId);			
			_player.loadVideoById(_video.actualId);
		}
	}
}